Как сделать первую букву заглавной в Excel

Как заменить первую строчную букву в ячейке на заглавную? Нужно ли нам вручную исправлять начальный символ в каждой ячейке? Сегодня я поделюсь тремя методами изменения первых букв в ваших текстовых значениях на заглавные.

Я считаю, что когда дело доходит до текста в Excel, одной из наиболее часто требуемых задач является иметь заглавную первую букву в ячейке. Всякий раз, когда у вас есть списки имен, продуктов, задач или чего-либо еще, вы наверняка обратите внимание, что некоторые из них (если не все) записаны только строчными буквами.

В одной из наших предыдущих статей мы обсуждали, как функция ПРОПНАЧ может спасти положение. Но поскольку она делает каждое слово в ячейке заглавным, а остальные буквы не изменяет, иногда она не может быть панацеей.

Давайте посмотрим, какие еще варианты у нас есть, чтобы решить эту проблему.

В Excel есть много полезных функций, подходящих для заглавной первой буквы в ячейках. Однако вы не можете иметь и данные, и формулу, которая ссылается на них, в одной ячейке. Таким образом, вам нужно создать вспомогательный столбец где-то на вашем листе, чтобы разместить там формулы. Когда это будет сделано и вычисления будут произведены, вы сможете заменить формулы их значениями.

Содержание

Начнем?

Как сделать первую букву заглавной, остальные — строчные

Наша задача - сделать заглавной только первую букву в ячейке Excel и при этом сделать строчными все остальные. В нашем примере сделаем первую букву текста заглавной в столбце B.

Установите курсор в ячейку C2 и введите туда следующую формулу:

=ЗАМЕНИТЬ(СТРОЧН(B2);1;1;ПРОПИСН(ЛЕВСИМВ(B2;1)))

Совет. Скорее всего, остальные строки будут заполнены скорректированной формулой автоматически. В противном случае вы можете быстро скопировать формулу вниз по столбцу , перетащив ее или дважды щелкнув по маленькому квадратику в правом нижнем углу ячейки с формулой.

Позвольте мне объяснить, что означает приведенная выше формула:

ПРОПИСН(ЛЕВСИМВ(B2;1)) преобразует первую букву ячейки B2 в заглавную. Для этого функция ЛЕВСИМВ извлекает из текста эту первую букву, а функция ПРОПИСН делает ее заглавной.
Функция ЗАМЕНИТЬ используется для того, чтобы гарантировать, что будет возвращен весь текст с заменой одной указанной буквы — в нашем случае первой.
Добавление СТРОЧН(B2) в качестве первого аргумента функции ЗАМЕНИТЬ позволяет нам сделать маленькими все остальные буквы:

как сделать первую букву в ячейке Excel заглавной

Таким образом, вы получаете ячейки, в которых только первая буква заглавная, а остальные – прописные.

Как видите, не всегда такие изменения корректны, так как в тексте ячейки могут встречаться имена, фамилии, названия, которые также должны начинаться с заглавной буквы.

Поэтому мы рассмотрим еще несколько формул, которые возвращают другой результат, нежели рассмотренный выше.

Первая буква заглавная, остальные не учитываются

Чтобы сделать первую букву ячейки заглавной, а остальные символы оставить как есть, мы воспользуемся той же формулой, что и выше, с небольшим изменением.

=ЗАМЕНИТЬ(B2;1;1;ПРОПИСН(ЛЕВСИМВ(B2;1)))

Как видите, мы удалили функцию СТРОЧН из формулы. Это небольшое изменение сделает первую букву заглавной, но при этом не изменит все следующие за ней буквы в ячейке:

Первая буква в ячейке заглавная, остальные не учитываются

Совет. Не забудьте скопировать формулу вниз, если Excel не сделал этого автоматически.

Для любителей разнообразия могу рекомендовать еще несколько формул, которые делают первую букву заглавной:

=ЗАМЕНИТЬ(B2;1;1;СИМВОЛ(КОДСИМВ(ПРОПНАЧ(B2))))

=ЗАМЕНИТЬ(B2;1;1;ПРОПНАЧ(ЛЕВСИМВ(B2)))

=ПРОПИСН(ЛЕВСИМВ(B2))&ПСТР(B2;2;10^5)

=ПРОПИСН(ПСТР(B2;1;1))&ПРАВСИМВ(B2;ДЛСТР(B2)-1)

=ПРОПИСН(ЛЕВСИМВ(B2))&ПРАВСИМВ(B2;ДЛСТР(B2)-1)

=ОБЪЕДИНИТЬ(" "; ИСТИНА; СЖПРОБЕЛЫ(ПРОПИСН(ЛЕВСИМВ(B2;1)) & СТРОЧН(ПСТР(B2; 2; ДЛСТР(B2)))))

Также могу предложить еще одну статью по этой теме: Как изменить регистр и поменять строчные буквы на заглавные в Excel.

Надеюсь, это будет вам полезно.

Как сделать первые буквы каждого слова заглавными

Чтобы сделать первую букву каждого слова в ячейке заглавной, вы можете попробовать функцию ПРОПНАЧ.

Синтаксис ее очень простой:

ПРОПНАЧ(ячейка)

Она делает заглавной первую букву в ячейке, а также все другие буквы, которые следуют после не-буквенных символов (цифр, пробелов, запятых, точек и т.д.)

Все прочие буквы она принудительно делает строчными. В некоторых случаях это может быть проблемой. Например, вместо «YouTube” вы получите “Youtube”, а вместо “iPhone” – “Iphone”.

Вот как эта функция работает с нашими данными:

=ПРОПНАЧ(B2)

функция ПРОПНАЧ делает первые буквы каждого слова заглавными

Кроме того, большими буквами теперь записаны предлоги и союзы, которые состоят из 1-2 букв. Это также не всем может нравиться.

Могу предложить вам 2 способа чтобы первые буквы всех слов были заглавные, кроме слов из 2 букв. Так мы сможем не менять буквы в предлогах и союзах.

Первый способ – при помощи формул. Сложность заключается в том, что в этой формуле используется функция ТЕКСТРАЗД, которая на момент написания этой статьи доступна только в Excel365.

Вот как это выглядит:

=ОБЪЕДИНИТЬ(" ";ИСТИНА; ЕСЛИ(ДЛСТР(ПРОПНАЧ(ТЕКСТРАЗД(B2;" ")))>2; ПРОПНАЧ(ТЕКСТРАЗД(B2;" "));ТЕКСТРАЗД(B2;" ")))

Как видите, все слова из одной и двух букв остались без изменений.

Второй способ – пользовательская функция VBA. Подробнее об этих функциях читайте здесь: Как создать пользовательскую функцию? и Как правильно сохранить и применять пользовательскую функцию Excel.

Вот пошагово порядок действий:

Откройте редактор VBA с помощью Alt + F11.
Вставьте новый модуль, выбрав Insert -> Module.
Вставьте следующий код в модуль:

Function ProperCase(text As String) As String
    Dim words() As String
    Dim i As Integer
    words = Split(text, " ")
    For i = LBound(words) To UBound(words)
        If Len(words(i)) > 2 Then
            words(i) = UCase(Left(words(i), 1)) & LCase(Mid(words(i), 2))
        Else
            words(i) = words(i)
        End If
    Next i
    ProperCase = Join(words, " ")
End Function