В статье показано, как определить среднее значение в Excel для разных типов данных с помощью формул СРЗНАЧ или СРЗНАЧА. Вы также узнаете, как использовать функции СРЗНАЧЕСЛИ и СРЗНАЧЕСЛИМН для усреднения ячеек, соответствующих определенным критериям.

Средняя зарплата… Средняя продолжительность жизни… Ежедневно мы с вами слышим эти словосочетания, служащие для описания множества одним единственным числом. Но, как ни странно, «среднее значение» — достаточно коварное понятие, часто вводящее в заблуждение обычного, неискушенного в математической статистике, человека. Например, в какой-то абстрактной компании работает десять сотрудников. Девять из них получают зарплату около 50 000 рублей, а один 1 500 000 рублей (по странному совпадению он же является генеральным директором этой компании).

В математике среднее называется средним арифметическим, и оно рассчитывается путем сложения группы чисел, а затем деления на количество этих чисел.

В приведенном выше примере средняя зарплата составляет: 195 000 рублей =(50000*9+1500000)/10. Вряд ли эта цифра соответствует реальной ситуации, но таковы расчёты среднего арифметического значения.

И всё же в большинстве случаев знать среднее весьма полезно.

Как посчитать среднее арифметическое в Экселе? Вам не нужно писать сложные математические выражения. Есть несколько функций «на все случаи жизни».

  • СРЗНАЧ (AVERAGE- а английском варианте) - рассчитать среднее арифметическое ячеек с числами.
  • СРЗНАЧА (или AVERAGEA) - найти среднее арифметическое ячеек с любыми данными (числа, логические и текстовые значения).
  • СРЗНАЧЕСЛИ (или AVERAGEIF) – среднее по заданному критерию.
  • СРЗНАЧЕСЛИМН (или AVERAGEIFS) – среднее ячеек, удовлетворяющих нескольким условиям.

Функция СРЗНАЧ.

СРЗНАЧ применяется для возврата среднего арифметического указанных ячеек.

СРЗНАЧ число 1; [число 2];…)

Число 1, 2 и так далее - числа, для которых вы хотите найти среднее. Первый аргумент обязателен, последующие - нет. В одну формулу может быть включено до 255 аргументов. Они могут быть представлены в виде чисел, ссылок на ячейки или диапазонов.

Использование функции СРЗНАЧ – на примерах.

СРЗНАЧ - одна из самых простых и простых в использовании функций Excel, и следующие примеры подтверждают это.

Пример 1. Расчет среднего из нескольких чисел.

Вы можете указать числа непосредственно. Например,

 =СРЗНАЧ(1;2;3;4) возвращает результат 2,5.

Чтобы вычислить среднее по столбцу, укажите ссылку на него целиком:
=СРЗНАЧ(A:A)

Чтобы получить  по строке, введите ссылку на нее:
=СРЗНАЧ(1:1)

Чтобы вычислить в каком-то диапазоне, укажите его:
=СРЗНАЧ(A1:C20)

Чтобы вернуть среднее из несмежных ячеек, запишите каждую ячейку отдельно, например
=СРЗНАЧ(A1; C1; D1)

И, естественно, ничто не мешает вам включать числа, ссылки и диапазоны в одну формулу. Например, следующее выражение вычисляет среднее из 2 диапазонов и 1 отдельного значения:

=СРЗНАЧ(B3:B5; C7:D9; B11)

Примечание. Если вы хотите округлить полученное число до ближайшего целого, примените одну из функций округления, например:

=ОКРУГЛ(СРЗНАЧ(B3:B5; B7:B9; B11);0)

Помимо чисел, вы можете использовать функцию СРЗНАЧ для вычисления среднего на основе других видов чисел, таких как проценты и время. Это показано в следующих примерах.

Пример 2. Расчет среднего процента.

Если у вас есть столбец с процентами на вашем листе, как вы получаете средний процент выполнения? Возьмём обычную формулу Excel для среднего :)

Примечание. Обратите внимание, что СРЗНАЧ учитывает и нулевые значения при расчете. А это существенно повлияет на итоговую цифру. Если вы предпочитаете исключать нули из расчета, возьмите вместо этого СРЗНАЧЕСЛИ, как будет показано чуть ниже. ССЫЛКА

Пример 3. Расчет среднего времени.

Этим совсем не так просто, как с обычными числами. Ведь время включает часы, минуты и секунды? Вычислять разные единицы времени вручную было бы очень сложно… но СРЗНАЧ отлично с этим справляется.

Важные особенности СРЗНАЧ!

Как вы только что видели, применять СРЗНАЧ очень просто. Тем не менее, у нее есть несколько особенностей, о которых вам нужно знать.

  • Нулевые значения (0) включены в расчет.
  • Текстовые строки, логические значения ИСТИНА и ЛОЖЬ, а также пустые ячейки — игнорируются. Если вы хотите включить в расчет логические и текстовые представления чисел, примените  СРЗНАЧА.
  • Учитываются логические значения, которые вы вводите непосредственно в выражение. Например, =СРЗНАЧ(ИСТИНА; ЛОЖЬ) возвращает 0,5, что является средним из 1 и 0.

Примечание. При использовании СРЗНАЧ в листах Excel, учитывайте различие между ячейками, содержащими нулевые значения, и реально пустыми. Нули считаются, а пустые - нет. Это может быть особенно важно, если опция «Показывать ноль в ячейках, которые содержат нулевые значения» не включена на данном листе. То есть, клетки с нулями внешне будут пустыми. Вы можете найти эту опцию в Эксель: Параметры  > Дополнительно > Параметры отображения листа .

Чем отличается функция СРЗНАЧА?

СРЗНАЧА аналогична СРЗНАЧ в том, что она вычисляет среднее арифметическое чисел. Разница в том, что СРЗНАЧА включает в расчет все непустые ячейки, независимо от того, содержат ли они числа, текст, логические ИСТИНА и ЛОЖЬ, или пустые строки, возвращаемые другими формулами.

СРЗНАЧА(значение1; [значение2];…)

значение1, 2,… - это цифры, массивы, ссылки на ячейки или диапазоны, которые вы хотите усреднить. Первый аргумент обязателен, другие (до 255) необязательны.

Она обрабатывает различные типы данных, такие как числа, текстовые строки и логические. Что нужно запомнить:

  • Пустые клетки таблиц игнорируются.
  • Текст, включая пустые строки (""), возвращаемые другими формулами, оценивается как 0.
  • Логическое ИСТИНА оценивается как 1, а ЛОЖЬ оценивается как 0.

Например, =СРЗНАЧА(2;ЛОЖЬ) дает нам 1, что является средним между 2 и 0.

=СРЗНАЧА(2;ИСТИНА) возвращает 1,5, что является средним  от 2 и 1.

На следующем скриншоте показаны два варианта расчёта для среднего значения в Excel, и разные результаты, которые они возвращают:

Поэтому, если вы не хотите включать в свои вычисления логические выражения и текстовые строки, используйте СРЗНАЧ, а не СРЗНАЧА.

Среднее по условию - функция СРЗНАЧЕСЛИ

СРЗНАЧЕСЛИ вычисляет среднее арифметическое всех ячеек, которые соответствуют заданным критериям.

СРЗНАЧЕСЛИ (диапазон; критерии; [диапазон_усреднения])

Она имеет следующие аргументы (первые 2 обязательны, последний – нет):

  • Диапазон - диапазон ячеек, которые будут проверены по заданным параметрам.
  • Критерии - условие, применяемое для определения, какие ячейки усреднять. Они могут быть представлены в виде числа, логического выражения, текста или ссылки, например, 5,> 5, «кот» или A2.
  • Диапазон усреднения - что вы хотите усреднить (он необязательный). Если опущено, функция будет считать по диапазону условия.

А теперь давайте посмотрим, как вы можете применить СРЗНАЧЕСЛИ на реальных рабочих листах, чтобы найти среднее ячеек, соответствующих вашим требованиям.

Точное соответствие критериям

Классическое применение СРЗНАЧЕСЛИ - это нахождение среднего арифметического ячеек, которые точно соответствуют заданному условию. 

В этом примере давайте усредним только продажи (B2: B8) для заказов на бананы (A2: A8):

=СРЗНАЧЕСЛИ($A$2:$A$8; $B$10; $B$2:$B$8)

Вместо того, чтобы вводить условие непосредственно в формулу, вы можете ввести его в отдельную ячейку ($B$10) и затем обратиться к ней. Это очень известный и всеми применяемый приём.

Примечание. Чтобы округлить возвращаемое число до определенного количества десятичных знаков, примените одну из функций округления Excel, или диалоговое окно «Формат ячеек», чтобы изменить только отображение числа на экране.

Например, чтобы округлить полученный выше результат до 2 десятичных знаков, вы можете заключить его в функцию ОКРУГЛ следующим образом:

=ОКРУГЛ(СРЗНАЧЕСЛИ(A2:A8;"бананы"; B2:B8);2)

Кроме того, вы можете выбрать ячейку с формулой (E1 в этом примере), нажмите комбинацию клавиш Ctrl + 1, чтобы открыть диалоговое окно «Формат ячеек». Затем перейдите на вкладку «Числовой» или «Денежный » и выберите количество десятичных разрядов, которые вы хотите показать. Помните, что в этом случае фактическое сохраненное значение не изменится, и точное неокругленное число будет использоваться во всех вычислениях, когда вы ссылаетесь на него в других формулах.

Частичное соответствие критериям (с символами подстановки).

Вы можете применить символы подстановки в аргументе критерия для выбора ячеек на основе частичного совпадения:

  • Вставьте знак вопроса (?), чтобы заменить любой отдельный символ.
  • Вставьте звездочку (*), чтобы заменить ею любую последовательность символов.
  • Чтобы найти реальный знак вопроса или звездочку, введите тильду (~) перед этим символом (то есть, ~? или ~*).

Предположим, что у вас есть 3 разных вида бананов, и вы хотите найти среднюю величину их продаж:

=СРЗНАЧЕСЛИ($A$2:$A$8; "*бананы"; $B$2:$B$8)

Если вашему ключевому слову может предшествовать и/или последовать какой-либо другой символ, добавьте звездочку * как перед словом, так и после него.

=СРЗНАЧЕСЛИ($A$2:$A$8; "*бананы*"; $B$2:$B$8)

Чтобы найти среднее по всем товарам, за исключением каких-либо бананов, запишите следующую формулу:

=СРЗНАЧЕСЛИ($A$2:$A$8; "<>*бананы*"; $B$2:$B$8)

Как применить числовые условия и логические операторы.

Довольно часто вам может потребоваться усреднить ячейки, в которых количество больше или меньше определенного числа. Например, есть перечень чисел в столбце A, и мы хотим найти среднее из тех из них, которые больше 10.

Правильный подход — заключить логический оператор и число в двойные кавычки. 

Итак, мы получили вот что:

=СРЗНАЧЕСЛИ($A$2:$A$7;">10")

Другая весьма распространенная проблема – как найти среднее чисел, которые не равны нулю. Для этого вам понадобится оператор «не равно» в аргументе критерия:

=СРЗНАЧЕСЛИ($A$2:$A$7;"<>0")

Как вы, возможно, заметили, мы не задействуем третий аргумент [диапазон усреднения] ни в одном из приведенных выше выражений, поскольку мы хотим считать по начальному диапазону.

Для пустых или непустых ячеек

При выполнении анализа данных в Excel часто может потребоваться найти среднее чисел, которые соответствуют либо пустым, либо непустым областям.

Среднее, если пусто.

Чтобы включить пустые ячейки, которые не содержат абсолютно ничего (без формулы, без строки нулевой длины), введите «=» в аргументе.

Например, вычислим среднее ячеек C2: C8, если клетка в столбце B в той же строке абсолютно пуста:

=СРЗНАЧЕСЛИ($B$2:$B$8; "="; $C$2:$C$8)

Чтобы усреднить значения, соответствующие визуально пустым ячейкам, включая те, которые содержат пустые строки, возвращаемые другими функциями (например, с формулой вроде = ""), запишите "". Например:

=СРЗНАЧЕСЛИ($B$2:$B$8; ""; $C$2:$C$8)

Среднее, если не пустое.

Чтобы найти среднее, соответствующее непустым ячейкам, введите «<>».

Например, так вычисляем среднеарифметическое C2:C8, если соответствующая позиция в столбце B не пуста:

=СРЗНАЧЕСЛИ($B$2:$B$8; "<>"; $C$2:$C$8)

Использование ссылок и других функций в описании условий.

Вместо того, чтобы записывать параметры подсчета непосредственно в формуле, вы можете обратиться к определенной ячейке, в которую можно вводить различные значения, не изменяя саму формулу. Так значительно уменьшается риск случайной ошибки при корректировке.

Если ссылка является критерием точного соответствия, то просто укажите ее в аргументе:

=СРЗНАЧЕСЛИ($B$2:$B$8;E1; $C$2:$C$8)

Если в качестве условия вы берёте логическое выражение со ссылкой или c другой функцией, нужно заключить логический оператор в «двойные кавычки» и добавить амперсанд (&) для их объединения.

Например, чтобы рассчитать средние продажи (C2: C8), превышающие указанное в E4:

=СРЗНАЧЕСЛИ($C$2:$C$8; ">"&$B$13)

С датами в B2: B8, приведенное ниже возвращает среднюю величину продаж (C2: C8), которые произошли до текущей даты:

=СРЗНАЧЕСЛИ($B$2:$B$8; "<="&"22-07-2020"; $C$2:$C$8)

Вместо прямого указания даты можно взять соответствующую функцию. К примеру,

=СРЗНАЧЕСЛИ($B$2:$B$8; "<="&СЕГОДНЯ(); $C$2:$C$8)

Среднее по нескольким условиям - функция СРЗНАЧЕСЛИМН

СРЗНАЧЕСЛИМН учитывает сразу несколько условий и возвращает среднеарифметическое ячеек, которые соответствуют всем указанным критериям.

СРЗНАЧЕСЛИМН(диапазон подсчёта, диапазон_критерия_1, критерий_1, [диапазон_критерия_2, критерий_2],…)

Она имеет следующие аргументы:

  • Диапазон_подсчёта - область ячеек, которые вы хотите усреднить.
  • диапазон_критерия_1, 2 ,… - от 1 до 127 диапазонов для проверки на соответствие указанным параметрам. Первый из них обязателен, последующие – по желанию.
  • Критерий_1, 2,… - от 1 до 127 критериев, определяющих, какие именно клетки следует усреднить. Они могут быть в виде числа, логического выражения, текста или ссылки. Первый обязателен, дополнительные – по необходимости.

Функция СРЗНАЧЕСЛИМН доступна в Excel 2016, Excel 2013, Excel 2011 для Mac, Excel 2010 и 2007.

Как уже упоминалось, СРЗНАЧЕСЛИМН находит среднее ячеек, которые соответствуют всем указанным вами критериям (логика «И»). По сути, вы применяете его совершенно аналогично СРЗНАЧЕСЛИ, за исключением того, что вы можете указать в ней несколько областей проверки и соответствующих условий.

Пример 1. Среднеарифметическое количество ячеек по нескольким параметрам (текст и число)

Предположим, что у вас есть список товаров в столбце A и суммы продаж в столбце B. Давайте выясним среднее продаж бананов, превышающее 100 единиц.

Здесь:

  • С2:С8 - ячейки, которые вы хотите усреднить, если выполняются оба условия;
  • Первое условие: A2:A8 (столбец «Товар»), а критерий_1 - «бананы»;
  • Второе условие - это С2:С8 (столбец «Продажи»), а критерий_2 - «> 100».

Собираем вышеперечисленные компоненты вместе. И если вы замените условия ссылками, вы получите нечто похожее на это:

=СРЗНАЧЕСЛИМН($C$2:$C$8; $A$2:$A$8;$C$10; $C$2:$C$8; ">"&$C$11)

Как видите, только две ячейки (С3 и С5) удовлетворяют обоим условиям, и поэтому только они и берутся для расчета.

Пример 2. Среднеарифметическое на основе критерия даты

В этом примере давайте посчитаем среднее количество товаров, доставленных до 22 июля 2020 года, статус которых определен (позиция в соответствующем столбце не пустая). С количеством, указанным в столбце D, датами в колонке В (критерий_1) и статусом в С (критерий_2), формула выглядит следующим образом:

=СРЗНАЧЕСЛИМН($D$2:$D$8; $B$2:$B$8; "<=22-07-2020"; $C$2:$C$8; "<>")

В критерии1 вы вводите дату, которой предшествует оператор сравнения. В критерии2 вы вводите «<>», который указывает включать только непустые ячейки в пределах столбца «Статус».

Примечание. Когда вы используете число или дату в сочетании с логическим оператором в указании условия, то заключайте эту комбинацию в двойные кавычки -  “<=22.07.2020”.

Что нужно запомнить!

СРЗНАЧЕСЛИ и СРЗНАЧЕСЛИМН имеют много общего, в частности:

  • При подсчёте пустые области, логические ИСТИНА/ЛОЖЬ и текст — игнорируются.
  • При оценке заданных условий пустые ячейки рассматриваются как нулевые (0).
  • Если область, по которой считаем среднее, содержит только пустые клетки или текст, то обе функции возвращают ошибку #ДЕЛ/0!.
  • Если ничего не соответствует требованиям, то также получаем ошибку #ДЕЛ/0!.

ОСОБЕННОСТИ

  • Диапазон для подсчёта СРЗНАЧЕСЛИ не обязательно должен быть того же размера, что и область условий. Однако фактические данные, с которыми работает функция, определяются размером аргумента усреднения. Другими словами, если записать выражение

=СРЗНАЧЕСЛИ($B$2:$B$10; «<>»; $C$2:$C$8)

то в любом случае находить среднее мы будем по $C$2:$C$8.

  • В отличие от СРЗНАЧЕСЛИ, СРЗНАЧЕСЛИМН требует, чтобы каждая область критериев была того же размера, что и область для подсчета. Иначе получаем ошибку #ЗНАЧ!.

Как усреднить числа по нескольким параметрам с помощью логики ИЛИ?

Поскольку СРЗНАЧЕСЛИМН работает с логикой «И», а СРЗНАЧЕСЛИ допускает только 1 критерий, нам придется составить нашу собственную формулу для усреднения с помощью логики «ИЛИ». 

Другими словами, мы составим выражение для вычисления среднего арифметического в Excel, если выполняется любое из указанных требований.

Пример 1. Среднее с логикой ИЛИ на основе нескольких текстовых критериев

Предположим, вы хотите получить средние продажи (C2: C8) как для бананов, так и для яблок (A2: A8). Чтобы рассчитать это, вам понадобится формула массива, включающая несколько функций Excel:

{=СРЗНАЧ(ЕСЛИ(ЕЧИСЛО(ПОИСКПОЗ(A2:A8;{"бананы";"яблоки"};0));B2:B8))}

Пожалуйста, помните, что формулы массива должны быть введены через Ctrl + Shift + Enter, а не просто ENTER.

Если товары, которые мы ищем, записать отдельно (скажем, в E1 и E2), то наш расчет будет выглядеть так:

{=СРЗНАЧ(ЕСЛИ(ЕЧИСЛО(ПОИСКПОЗ(A2:A8;E1:E2;0));B2:B8))}

Из всех формул усреднения Excel, которые обсуждались до сих пор, это самая хитрая (хотя осталось еще два примера ;)

Как это работает?

Для наших любопытных и вдумчивых читателей, которые хотят не только механически применять рекомендации, но и понимать, что же они делают, даем подробное объяснение логики расчетов.

В начале функция ЕСЛИ определяет, какие значения в исходном диапазоне соответствуют любому из указанных параметров, и передает их в СРЗНАЧ. Вот как:

ПОИСКПОЗ берёт исходные данные в A2:A8 в качестве условий поиска и сравнивает каждое из них с массивом поиска, представленным критериями в E1: E2. 

3- й аргумент, установленный в 0, указывает искать точные совпадения:

ПОИСКПОЗ(A2:A8,E1:E2,0)

Когда совпадение найдено, программа возвращает относительную позицию в массиве поиска, в противном случае ошибку #Н/Д!.

{#Н/Д!; 1; 2; 1; 2; #Н/Д!; 1}

ЕЧИСЛО преобразует любые числа в ИСТИНА, а ошибки в ЛОЖЬ:

{ЛОЖЬ; ИСТИНА; ИСТИНА; ИСТИНА; ИСТИНА; ЛОЖЬ; ИСТИНА}

Этот массив отправляется на логическую проверку ЕСЛИ. 

 Она заменяет позиции, соответствующие ИСТИНА в приведённом выше массиве, фактическими значениями из B2: B8:

{ЛОЖЬ; 80; 130; 120; 70; ЛОЖЬ; 90}

Этот окончательный массив передается в СРЗНАЧ, которая вычисляет, игнорируя логические значения.

Пример 2. Среднее с логикой ИЛИ на основе числовых критериев с операторами сравнения

Если вы хотите найти среднее арифметическое на основе нескольких числовых критериев и условий больше/меньше, чем в сочетании с логикой ИЛИ, то формула, рассмотренная в предыдущем примере, не будет работать. Ведь вы не можете поместить эти логические выражения в массив. Решение заключается в применении функции СУММ в формуле массива.

Предположим, у вас есть количество в столбце B и сумма в столбце C, и вы хотите усреднить суммы, которые больше 50 в столбце B или C. При этом вы хотите избежать дубликатов, то есть не считать строку дважды, если число больше 50 в обоих столбцах.

Вот рабочий пример:

{=СУММ(ЕСЛИ((C2:C8+D2:D8>50);D2:D8;0))/СУММ( --((C2:C8+D2:D8)>50))}

Помните, что это формула массива, и поэтому вы должны нажать Ctrl + Shift + Enter и ввести ее правильно.

Как видите, выражение состоит из 2 частей. В первой части вы применяете функцию ЕСЛИ с оператором ИЛИ в аргументе  (C2:C8> 50) + (D2:D8> 50). Как вы, вероятно, знаете, в формулах массива плюс (+) действует как оператор ИЛИ.

Итак, первая часть складывает числа в столбце C, если выполняется любое из условий. 

Вторая часть возвращает количество таких ячеек, а затем вы делите сумму на количество, чтобы найти среднеарифметическое.

И, естественно, вы можете указать разные условия для каждого диапазона. Например, чтобы усреднить продажи, если столбец C больше 50 или столбец D больше 100, используйте следующие выражения: (C2: C8> 50) + (D2: D8> 100). Всё целиком будет выглядеть следующим образом:

=СУММ(ЕСЛИ((C2:C8>50)+(D2:D8>100);D2:D8;0))/СУММ(--((C2:C8>50)+(D2:D8>100)))

Пример 3. Среднее с логикой ИЛИ на основе пустых/непустых ячеек

Средняя формула с несколькими условиями ИЛИ, соответствующими пустым и непустым ячейкам, очень похожа на ту, которую мы только что обсуждали.

Для непустых ячеек.

Следующая формула массива находит среднее количество (столбец B), если указана либо дата (столбец B), либо статус (столбец C), т. е. если столбцы B или C не пустые.

Чтобы сделать её более компактной, вы можете объединить диапазоны с помощью амперсанда (&):

{=СУММ(ЕСЛИ((B2:B8&C2:C8)<>"";D2:D8;0))/СУММ( --((B2:B8&C2:C8)<>""))}

Для пустых ячеек.

Чтобы усреднить числа в столбце D, соответствующие пустым ячейкам в B или C, замените непустой оператор (<> "") пустым оператором (= ""). 

Объединение диапазонов при помощи амперсанда не будет работать в этом случае. 

Это также формула массива, поэтому не забудьте нажать Ctrl + Shift + Enter.

{=СУММ(ЕСЛИ(--((B2:B8="") + (C2:C8=""))>0;D2:D8;0)) / СУММ(--(((B2:B8="") + (C2:C8=""))>0))}

Вот как рассчитывается среднее в Excel. 

Я благодарю вас за чтение и надеюсь еще не раз увидеть вас в нашем блоге!